package IMPL::Web::Application;
use strict;
use warnings;

use base qw(IMPL::Config IMPL::Object::Singleton);

require IMPL::Web::Application::Action;
require IMPL::Web::Application::Response;

use IMPL::Class::Property;
use CGI;

__PACKAGE__->PassThroughArgs;

BEGIN {
    public property handlerError => prop_all;
    public property factoryAction => prop_all;
    public property handlersQuery => prop_all | prop_list;
    public property responseCharset => prop_all;
    public property options => prop_all;
}

# custom factory
sub new {
    my ($self,$file) = @_;
    
    return $self->LoadXMLFile($file);
}

sub CTOR {
	my ($this) = @_;
	
	$this->factoryAction('IMPL::Web::Application::Action') unless $this->factoryAction;
	$this->responseCharset('utf-8') unless $this->responseCharset;
}

sub Run {
    my ($this) = @_;
    
    while (my $query = $this->FetchRequest()) {
        
        my $action = $this->factoryAction->new(
        	query => $query,
        	application => $this, 
        );
        
        $action->response->charset($this->responseCharset);
        
        $action->ChainHandler($_) foreach $this->handlersQuery;
        
        $action->Invoke();
        
        $action->response->Complete;
    }
}

{
	my $hasFetched = 0;

	sub FetchRequest {
		return undef if $hasFetched;
		$hasFetched = 1;
		return CGI->new();
	}
}

1;

__END__

=pod

=head1 SYNOPSIS

require MyApp;
MyApp->spawn('app.config')->Run();

=head1 DESCRIPTION

Зкземпляр приложения содержит в себе глобальные настройки, реализует контроллер запросов,
в качестве источника запросов используется CGI или иной совместимый модуль.

Процесс обработки запроса состоит из следующих частей

1. Получение cgi запроса
2. Вызов модуля для инициализации объекта действия
3. Инициализация контекста выполнения 
4. Выполнение запроса
5. Преобразование полученных данных в тело ответа




=cut